VB.Net

Implementing a News Aggregator in Silverlight and VB.Net #2 Accessing our database from VB.Net

paulschapman — Fri, 05 Sep 2008 03:57:15 GMT

In the years since the .Net runtime was first released I've seen a number of ways of accessing a SQL database from within VB.Net (or C#). One person I worked with had a nifty utility which would take any database and generate all the code to access it. It has been on my list of jobs to do to implement my own such tool but like other jobs, such as winning the National Lottery or winning a high stakes poker game I have never got around to it. OK the poker game is something my wife will have to do - she is better at poker than me.

What I do have is a class which encapsulates the functions I need to execute stored procedures on the database. All my database access is executed by inheriting from the following class;

Imports Microsoft.VisualBasic
Imports System.Data
Imports System.Data.SqlClient

Imports System
Imports System.Xml
Imports System.Xml.Linq

Public MustInherit Class DataEngine
    Protected _Connection As SqlConnection
    Protected _Command As SqlCommand

    Sub New()
        _Connection = New SqlConnection()
        _Command = New SqlCommand()
    End Sub

    Sub New(ByVal ConnectionString As String)
        _Connection = New SqlConnection(ConnectionString)
        _Command = New SqlCommand()
    End Sub

    Protected Property ConnectionString As String
        Get
            Return _Connection.ConnectionString
      End Get
        Set(ByVal value As String)
            _Connection.ConnectionString = value
        End Set
    End Property

    Protected Function ExecuteStoredProcedure(ProcedureName As String, Table As String) As DataTable
        Dim _DataTable      As DataTable
        Dim _DataAdapter    As SqlDataAdapter
        Dim _DataSet        As DataSet = New DataSet()

        Try

            If _Connection.State = ConnectionState.Closed Then
                _Connection.Open()
            End If

            With _Command
                .CommandText = ProcedureName
                .CommandType = CommandType.StoredProcedure
                .Connection = _Connection
            End With

            _DataAdapter = New SqlDataAdapter(_Command)

            _DataAdapter.Fill(_DataSet,Table)
            _DataTable = _DataSet.Tables(Table)
        Catch ex As Exception
            Throw ex
        End Try

        Return _DataTable
    End Function

    Protected Sub ExecuteStoredProcedure(ProcedureName As String)
        Try

            If _Connection.State = ConnectionState.Closed Then
                _Connection.Open()
            End If

            With _Command
                .CommandText = ProcedureName
                .CommandType = CommandType.StoredProcedure
                .Connection = _Connection

                .ExecuteNonQuery()
            End With

        Catch ex As Exception
            Throw ex
        End Try
    End Sub

    Protected Property Command As SqlCommand
        Get
            Return _Command
        End Get
        Set(ByVal value As SqlCommand)
            _Command = value
        End Set
    End Property

End Class

First thing to notice about this class is that it is marked MustInherit you cannot directly create an instance of this class. What you do is create a class which inherits from this class. In this way the common tasks required; which summarised is open a connection to the database and execute stored procedures. There are two types essentially; a stored procedure which returns a table, and one that does not.

The class has two constructors. One that creates the basic database access objects; the connection and the command, and another which allows us to pass a connection string.

Next is a property which exposes the connection string to any child of this class. This is the other means for setting the connection string, although to be honest as a general rule I prefer to do that at the when an instance is created.

The next two procedures take advantage of overloading, allowing us to pass an optional table name for the results.

Finally the last property allows access to the command object.

We can use this class to access the database created earlier with the following class;

Imports Microsoft.VisualBasic
Imports System.Data
Imports System.Data.SqlClient
Imports System.Configuration.ConfigurationManager

Public Class SimplicitaDatabase
        Inherits DataEngine

    Public Sub New

        ConnectionString = ConnectionStrings("SimplicitaDB").ConnectionString

    End Sub

    Public Function Register(Name As String,Address1 As String, Address2 As String, Town As String, County As String, Postcode As String, Tel As String,Fax As String, Email As String, WebAddress As String,Password As String) As DataTable
        Dim dt As DataTable = New DataTable()

        Dim SqlParamName        As SqlParameter = New SqlParameter("Name",SqlDbType.VarChar)
        Dim SqlParamAddress1    As SqlParameter = New SqlParameter("Address1",SqlDbType.VarChar)
        Dim SqlParamAddress2    As SqlParameter = New SqlParameter("Address2",SqlDbType.VarChar)
        Dim SqlParamTown       As SqlParameter = New SqlParameter("Town",SqlDbType.VarChar)
        Dim SqlParamCounty      As SqlParameter = New SqlParameter("County",SqlDbType.VarChar)
        Dim SqlParamPostcode    As SqlParameter = New SqlParameter("Postcode",SqlDbType.VarChar)
        Dim SqlParamTel         As SqlParameter = New SqlParameter("Telephone",SqlDbType.VarChar)
        Dim SqlParamFax         As SqlParameter = New SqlParameter("Fax",SqlDbType.VarChar)
        Dim SqlParamEmail       As SqlParameter = New SqlParameter("Email",SqlDbType.VarChar)
        Dim SqlParamWebAddr     As SqlParameter = New SqlParameter("WebAddress",SqlDbType.VarChar)
        Dim SqlParamPassword    As SqlParameter = New SqlParameter("Password",SqlDbType.VarChar)

        Try

          SqlParamName.Value      = Name
            SqlParamAddress1.Value = Address1
            SqlParamAddress2.Value = Address2
            SqlParamTown.Value      = Town
            SqlParamCounty.Value    = County
            SqlParamPostcode.Value = Postcode
            SqlParamTel.Value       = Tel
            SqlParamFax.Value       = Fax
            SqlParamEmail.Value     = Email
            SqlParamWebAddr.Value   = WebAddress
            SqlParamPassword.Value = Password

            With Command.Parameters
                .Clear()
                .Add(SqlParamName)
                .Add(SqlParamAddress1)
                .Add(SqlParamAddress2)
                .Add(SqlParamTown)
                .Add(SqlParamCounty)
                .Add(SqlParamPostcode)
                .Add(SqlParamTel)
                .Add(SqlParamFax)
                .Add(SqlParamEmail)
                .Add(SqlParamWebAddr)
                .Add(SqlParamPassword)
            End With

            dt = ExecuteStoredProcedure("RegisteredUser.Register","Result")

        Catch ex As Exception
            Throw
        End Try

        Return dt
    End Function

    Public Function RetrieveNewsfeeds As DataTable
        Dim dt As DataTable = New DataTable

        With Command.Parameters
            .Clear()
        End With

        dt = ExecuteStoredProcedure("NewsAggregator.RetrieveNewsFeeds","NewsFeeds")

        Return dt
    End Function

    Public Function RetrieveLatestStories As DataTable
        Dim dt As DataTable

        With Command.Parameters
            .Clear()
        End With

        dt = ExecuteStoredProcedure("NewsAggregator.RetrieveLatestStories","NewsStories")

        Return dt
    End Function

    Public Sub WriteNewsStory ( Title As String, Link As String, Desc As String, Supplier As String)
        Dim SqlParamTitle       As SqlParameter = New SqlParameter("Title",SqlDbType.VarChar)
        Dim SqlParamLink        As SqlParameter = New SqlParameter("Link",SqlDbType.VarChar)
        Dim SqlParamDesc        As SqlParameter = New SqlParameter("Desc",SqlDbType.VarChar)
        Dim SqlParamSupplier    As SqlParameter = New SqlParameter("Supplier",SqlDbType.VarChar)

        SqlParamTitle.Value     = Title
        SqlParamLink.Value      = Link
        SqlParamDesc.Value      = Desc
        SqlParamSupplier.Value = Supplier

        With Command.Parameters
            .Clear()
            .Add(SqlParamTitle)
            .Add(SqlParamLink)
            .Add(SqlParamDesc)
            .Add(SqlParamSupplier)

        End With

        ExecuteStoredProcedure("NewsAggregator.WriteNewsStory")

    End Sub
End Class

And that is the code for accessing the database created in part one.

Implementing a News Aggregator in Silverlight and VB.Net #1 - Creating SQL Database to store the news details

paulschapman — Thu, 04 Sep 2008 03:48:27 GMT

For one of my projects I need to have Business News headlines displayed on the front page, to give me greater control as to which headlines and from which feeds I use I'm going to have the aggregator call each feed and store the article details in a SQL database.

Schemas

I'm going to use schemas in designing my database. The use of these changed in SQL 2005 so that each one is a distinct namespace, independent of the user who created it. This will allow me to group related tables together, but it also allows you to use the same table name for different items. For example in an accounts system you have Sales accounts and Purchase accounts. You could of course create one table called SalesAccount and another called PurchaseAccount. With schemas we create ourselves two schemas one called SalesLedger and one called PurchaseLedger. Each schema has a table called 'Accounts'.

So first task is to create the schema that will hold our News. The following line of T/SQL will create our Namespace;

CREATE SCHEMA [NewsAggregator] AUTHORIZATION [dbo]
GO

Creating our tables

Now we have our schema the next thing is the tables that will store the feeds we are going to read, and the news headlines. Not a lot special in these ones to be honest. We need two tables; one to store the feeds that we will be aggregating and the second to store the headlines. The following T/SQL will create these tables;

CREATE TABLE [NewsAggregator].[NewsStories](
                  [Id] [bigint] IDENTITY(1,1) NOT NULL,
                  [Title] [varchar](127) NOT NULL,
                  [Link] [varchar](max) NOT NULL,
                  [Desc] [varchar](max) NULL,
                  [Supplier] [varchar](20) NOT NULL,
                  [DateAdded] [datetime] NOT NULL
                       CONSTRAINT [DF_NewsStories_DateAdded]
                       DEFAULT (getdate())
             ) ON [PRIMARY]

CREATE TABLE [NewsAggregator].[NewsFeeds](
                  [Id] [bigint] IDENTITY(1,1) NOT NULL,
                  [Link] [varchar](max) NOT NULL,
                  [Supplier] [varchar](30) NOT NULL,
                  [Weight] [smallint] NULL
             ) ON [PRIMARY]

So there is our two tables. I have added a 'weight' field to the table of feeds. How this works will be clear later, however it is here to allow us to control how many articles from each feed we are displaying.

Now when developing I like to keep things separated. For this reason I like to do all my database access via Stored Procedure. The practical upshot of this is that any differences in the dialect of SQL you are using should be hidden behind the stored procedure making it a lot easier to covert the whole thing to another database.

Stored Procedures

Our feeds are retrieved by making a call to RetrieveNewsFeeds. Taking note of the fact that I am using a schema called NewsAggregator the code to create this stored procedure is as follows;

CREATE PROCEDURE [NewsAggregator].[RetrieveNewsFeeds]
AS
BEGIN
SET NOCOUNT ON;
     SELECT Id,
            Link,
            Supplier
     FROM   NewsAggregator.NewsFeeds
END

This simply returns the results of select statement. I'm not interested in the order so to speed things along no sorting is done. Next having retrieved our news feeds we need to have a means of writing the headlines to our database;

CREATE PROCEDURE [NewsAggregator].[WriteNewsStory]
      @Title      VarChar(127),
      @Link       VarChar(MAX),
      @Desc       VarChar(MAX),
      @Supplier   VarChar(20)
AS
BEGIN

      Declare @StoryCount BigInt

      SET NOCOUNT ON;

      Set @StoryCount = (Select Count(*) As Counter From NewsAggregator.NewsStories
                         Where Link = @Link)

      If @StoryCount = 0
      Begin
            INSERT INTO NewsAggregator.NewsStories
                        (Title, Link, [Desc], Supplier)
            VALUES      (@Title,@Link,@Desc,@Supplier)
      End
END

This is fairly simple as a stored procedure. We first look for the story link in the database to see if it has been read before. If not then the story gets added to the database.

Now we have our feed suppliers, and we can write the stories to our database. The final stored procedure is to recover the files from the database.

First off the procedure opens up a cursor to access the list of feed suppliers. Normally I would not use a cursor which are notoriously slow in SQL Server but it does provide a simple mechanism for progressing through a table.

CREATE PROCEDURE [NewsAggregator].[RetrieveLatestStories]
AS
BEGIN
     Declare @Supplier VarChar(30)
     Declare @Weight SmallInt
     Declare @Result As Table
     (
          Title VarChar(127),
          Link VarChar(Max),
          [Desc] VarChar(Max)
     )

     Declare FeedSuppliers Cursor For
          SELECT Supplier,
                 Weight
          FROM   NewsAggregator.NewsFeeds

     Open FeedSuppliers
     Fetch FeedSuppliers Into @Supplier,@Weight

     While @@Fetch_Status = 0
     Begin
          Insert Into @Result (Title,Link,[Desc])
          Select   Top (@Weight)Title,Link,[Desc]
          From     NewsAggregator.NewsStories
          Where    Supplier = @Supplier
          Order By DateAdded Desc

          Fetch FeedSuppliers Into @Supplier,@Weight
     End

     Close FeedSuppliers
     Deallocate FeedSuppliers

     Select * From @Result
END

While we are moving through the table of suppliers we retrieve from the list of stories the latest for each supplier based on the weight. If the weight is 1 then we retrieve 1 story, 2 and 2 stories 3, 3 stories etc. This weight places a bias in the display of stories allowing us to control the stories from each supplier. and the following will store the news headlines